void startupPost()
{
	int 				cuentaSesionActiva = 0;
	UserId 				IdUsuario;
	SysClientSessions 	_SysClientSessions;
	;
	 
	IdUsuario = curuserid(); 	// Capturamos el id del usuario
 
	while select RecId from _SysClientSessions order by login_time desc
		  where _SysClientSessions.userId == curuserid() && _SysClientSessions.Status == 1
	{
		if (_SysClientSessions.RecId)
			cuentaSesionActiva = cuentaSesionActiva + 1; //Acumula el número de logins activos del usuario en el sistema
		else
			cuentaSesionActiva = 0;
	}
	 
	if (cuentaSesionActiva > 1)
	{
		infolog.shutDown(false);
	} 
}

static void DAXExport(TableId tableId)
{
	DictTable dt;
	DictField df;
	Common c;
 
 
	CommaIO cio;
	Container con, conSkip;
 
	int field, counter;
	str line, fieldName;
	str fileName;
	;
 
	StartLengthyOperation();
 
	//Access Table based on TableId
	dt = new DictTable(tableId); //For Table schema
	c = dt.makeRecord();         //To access records
	c.selectForUpdate(false);
 
	//Create temporary file
	fileName = strFmt('%1\\ax_%2.csv', WinAPI::getTempPath(), dt.name());
	cio = new CommaIO(fileName, "W");
 
	if(cio)
	{
		cio.outFieldDelimiter(';');
 
		//Column header
		line = "";
		for(field = 1; field <= dt.fieldCnt(); field++)
		{
			//Skip System Columns
			switch(dt.fieldName(dt.fieldCnt2Id(field)))
			{
				case 'modifiedDateTime':
				case 'dEL_ModifiedTime':
				case 'modifiedBy':
				case 'modifiedTransactionId':
				case 'createdDateTime':
				case 'dEL_CreatedTime':
				case 'createdBy':
				case 'createdTransactionId':
				case 'dataAreaId':
				case 'sequenceNum':
				case 'recVersion':
				case 'unionAllBranchId':
				case 'rowNumber':
				case 'RecId':
				case 'TableId':
				conSkip = conins(conSkip, maxint(), field);
				break;
 
				default:
				con = conins(con,field,dt.fieldName(dt.fieldCnt2Id(field)));
			}
		}
 
		cio.writeExp(con);
		con = conNull();
 
		//Table records
		while select c
		{
			line = "";
			for (field = 1; field <= dt.fieldCnt();field++)
			{
				if(0 == confind(conSkip, field))
				con = conins(con, field, c.(dt.fieldCnt2Id(field)));
			}
 
			cio.writeExp(con);
			con = conNull();
 
			counter++;
		}
	}
 
	EndLengthyOperation();
	info(strfmt("%1 registros de la tabla '%2' exportados", counter, dt.name()));
 
	//Open CSV file in registered app
	WinAPI::shellExecute(fileName);
}

server static void DAXExecuteSQL(str    _sql)
{
	/* Método para ejecutar directamente sql sobre base de datos - www.dynamicsax.es */
	str                           ddl = '';
	SqlStatementExecutePermission ssep;
	Statement                     statement;
	Connection                    connection;
	;
 
	ddl = _sql;
 
	connection = new Connection();
	connection.ttsbegin();
 
	ssep = new SqlStatementExecutePermission(ddl);
	ssep.assert();
	statement = connection.createStatement(ResultSetType::Dynamic, ResultSetConcurrency::Updatable);
 
	// BP deviation documented
	statement.executeUpdate(ddl);
	connection.ttscommit();
}

DAXExecuteSQL('Delete custTableTmp');